#
# configure.in: used by automake and autoconf to build configure
#
AC_INIT([Onions/onions.ads])
#
# Package Description and Platform Checks
#
AC_CANONICAL_SYSTEM
AM_INIT_AUTOMAKE(libwww-ada95, 1.00)
AM_CONFIG_HEADER([Onions/config.h])
#
AC_MSG_CHECKING(which platform-specific variant to use)
AC_ARG_WITH(platform,
 [  --with-platform=letter  Select another platform's specific files (debug)],
 [PLATFORM_SPECIFIC="${withval}"],
[case "${target}" in
  sparc-sun-solaris2*) PLATFORM_SPECIFIC=s;;
  sparc-sun-sunos4*)   PLATFORM_SPECIFIC=u;;
  i?86-*-linux*)       PLATFORM_SPECIFIC=a;;
  i?86-*-cygwin32)     PLATFORM_SPECIFIC=w;;
  mips-sgi-irix*)      PLATFORM_SPECIFIC=g;;
  mips-sni-sysv4)      PLATFORM_SPECIFIC=x;;
  hppa*-hp-hpux*)      PLATFORM_SPECIFIC=h;;
  *)                   PLATFORM_SPECIFIC=e;;
esac])
AC_SUBST(PLATFORM_SPECIFIC)
[case "${PLATFORM_SPECIFIC}" in
   s) PSNAME="Solaris";;
   u) PSNAME="SunOS";;
   a) PSNAME="Linux";;
   w) PSNAME="Windows NT";;
   g) PSNAME="SGI";;
   x) PSNAME="SNI";;
   h) PSNAME="HP";;
   e) PSNAME="Empty";;
   *) PSNAME="Unknown (${PLATFORM_SPECIFIC})";;
esac]
AC_MSG_RESULT($PSNAME)
#
# Figure out what the string aggregate is for a new-line
#
[case "${PLATFORM_SPECIFIC}" in
   w) OS_NEW_LINE_AGGREGATE="(1 => Ascii.CR, 2 => Ascii.LF)";;
   *) OS_NEW_LINE_AGGREGATE="(1 => Ascii.LF)";;
esac]
AC_SUBST(OS_NEW_LINE_AGGREGATE)
#
# Program Checks
#
AC_PROG_CC
AC_ISC_POSIX
AM_PROG_CC_STDC
AM_CYGWIN32
AC_PROG_RANLIB
AM_PROG_INSTALL
#
GNATMAKE="gnatmake"
AC_SUBST(GNATMAKE)
#
# Library Checks
#
[case "${PLATFORM_SPECIFIC}" in
   s) OS_LINKER_OPTS="   pragma Linker_Options (\"-lnsl\"); pragma Linker_Options (\"-lsocket\");";;
   w) OS_LINKER_OPTS="   pragma Linker_Options (\"-lwsock32\");";;
   x) OS_LINKER_OPTS="   pragma Linker_Options (\"-lnsl\"); pragma Linker_Options (\"-lsocket\");";;
   *) OS_LINKER_OPTS="";;
esac]
AC_SUBST(OS_LINKER_OPTS)
#
AC_ARG_WITH(extra-libs,
 [  --with-extra-libs=libs  Add extra libraries when building a program],
 [EXTRA_LIBS="${withval}"])
AC_SUBST(EXTRA_LIBS)
#
# Header File Checks
#
AC_HEADER_STDC
AC_HEADER_DIRENT
AC_HEADER_TIME
AC_CHECK_HEADERS(sys/time.h)
AC_CHECK_HEADERS(poll.h)
#
# Typedef Checks
# Structure Checks
# Library Function Checks
#
AC_CHECK_FUNCS(poll)
AC_FUNC_CLOSEDIR_VOID
AC_CHECK_FUNCS(readdir_r)
#
# Check for maintainer mode
#
AC_ARG_ENABLE(debug,
[  --enable-debug          Turn on debugging options],
[GNATFLAGS="-gnataov"],
[GNATFLAGS="-gnatn"])
AC_SUBST(GNATFLAGS)
#
# Output
#
AC_OUTPUT([Makefile Onions/Makefile Onions/onions-os.ads WWW/Makefile Examples/Makefile])